rem Twister ....... rev 3.1
      rem A J Tooth//Xmas 2007
      
      rem Preamble==================================
      on error if (err=17) then quit
      *FLOAT 64
      himem=lomem + 100000000
      install @lib$+"MyUtils.bbc"
      install @lib$+"BMP_Utils.bbc"
      rem Preamble==================================
      
      rem Intro
      proc_intro
      
      rem Maximise window
      proc_fullscreen(xscreen%,yscreen%)
      
      rem Get a picture
      proc_GetPic
      
      rem Setup 256 sub-bitmaps
      proc_subset
      
      rem Setup ASM
      proc_ASMsetup
      
      rem Split the picture
      proc_split
      
      a$="" : a%=0 : ch%=1
      origin xscreen%,yscreen%
      repeat
        rem Display sub-pics
        proc_subdisp(a%)
        
        rem Update angle
        proc_event(a$,b&)
        
        case asc(a$) of
          when 137,140: a%+=1
          when 136,141: a%-=1
        endcase
        if a%>90 then a%=90
        if a%<-90 then a%=-90
        
      until a$=" " or b&<>0
      
      if b&=4 then run else quit
      
      quit
      rem End of Program ========================================================
      rem =======================================================================
      
      rem Intro
      def proc_intro
      
      rem Maximise screen
      proc_maxim(xscreen%,yscreen%)
      colour 132,25,0,0 : colour 132 : colour 0,25,0,0 : cls
      
      proc_locback(50,fn_adapt(1,800),1500,fn_adapt(1,600),25,0,0)
      
      msg$="\2This program cuts a picture up into \1N x N \2pieces"
      proc_msg("Georgia",12,"B",150,fn_adapt(1,1350),msg$)
      msg$="\2It then rotates the pieces according to an angle determined by \nrotating the \3mouse wheel \2or pressing the \3left/right arrows"
      proc_msg("Georgia",12,"B",150,fn_adapt(1,1300),msg$)
      msg$="\2Then at any time \3left-click \2to choose another picture, or \3right click \2to \1QUIT"
      proc_msg("Georgia",12,"B",150,fn_adapt(1,1200),msg$)
      
      msg$="\1First, you need to choose the number of pieces to chop up the picture;\n\3rotate the mouse wheel \1or press the \3up/down arrows \1then \3left-click \1 to select"
      proc_msg("Georgia",12,"B",150,fn_adapt(1,1150),msg$)
      msg$="\3Pieces="
      proc_msg("Georgia",12,"B",150,fn_adapt(1,1050),msg$)
      
      Sub%=fn_islct(8,16,256,300,1050,2)
      
      msg$="\2Now press \3any key \2or \3left-click \2to select a picture"
      proc_msg("Georgia",12,"B",150,fn_adapt(1,1000),msg$)
      
      proc_event(a$,b&)
      endproc
      rem ==================================================================
      
      rem Prints the backdrop for the screen message
      def proc_locback(Xs%,Ys%,Ws%,Hs%,Rr&,Gg&,Bb&)
      local h&,Rf&,Gf&,Bf&
      
      for h&=0 to 50
        Rf&=Rr&*h&/50 : Gf&=100*(50-h&)/50 + Gg&*h&/50 : Bf&=Bb&*h&/50
        colour 15,Rf&,Gf&,Bf& : gcol 15
        rectangle fill Xs%+h&,Ys%+h&,Ws%-2*h&,Hs%-2*h&
      next h&
      endproc
      rem ========================================================================
      
      rem Parameter selection function - integers
      def fn_islct(Mn%,Typ%,Mx%,Xp%,Yp%,Oc&) : local x%, y%, b&, cur%, in&
      
      rem Mouse debounce routine
      repeat
        mouse x%,y%,b&
      until b&=0
      
      colour 1
      cur%=Typ%
      curold%=cur%
      repeat
        msg$="\0"+str$(curold%)
        proc_msg("Georgia",12,"B",Xp%,fn_adapt(1,Yp%),msg$)
        
        msg$="\"+str$(Oc&)+str$(cur%)
        proc_msg("Georgia",12,"B",Xp%,fn_adapt(1,Yp%),msg$)
        
        mouse x%,y%,b&
        sys "Sleep",10
        rem Raise / lower parameter if mouse wheel rotated
        in&=inkey(2)
        case in& of
          when 139,141: curold%=cur% : if cur%>Mn% then cur%/=2
          when 138,140: curold%=cur% : if cur%<Mx% then cur%*=2
          otherwise
            rem Do Nothing
        endcase
      until b&=4
      =cur%
      rem ========================================================================
      
      rem Get a picture
      def proc_GetPic
      
      rem Choose a picture
      proc_pichoose(Name$, FulName$, Pre$, wdth%, hght%, lgth%, pic%)
      Wlim%=((wdth%*3+3)and-4)
      
      rem Set the scaling
      proc_scale(xscreen%,yscreen%,wdth%,hght%,xb%,yb%,xc%,yc%)
      
      rem Display the picture initially
      proc_BMP_Disp(xc%,yc%,pic%,xb%,yb%)
      
      endproc
      rem ==================================================================
      
      rem Setup 256 sub-bitmaps
      def proc_subset
      local h&,v&,pcn%
      
      rem Parameters for sub-bitmaps
      Sx%=wdth%/Sub% : Sy%=hght%/Sub% : Slim%=((Sx%*3+3)and-4)
      
      B_size%=Sy%*Slim% + 54
      
      rem Reserve sufficient space for 256 sub-pictures
      Size%=Sub%*Sub%*B_size%
      dim subpics% Size%
      
      for v&=0 to Sub%-1
        for h&=0 to Sub%-1
          
          pcn%=subpics% + (v&*Sub% + h&)*B_size%
          
          rem Provide a bitmap with a header
          proc_bmpheader(Sx%,Sy%,B_size%,pcn%)
          
        next h&
      next v&
      endproc
      rem ==================================================================
      
      rem Provide a bitmap with a header
      def proc_bmpheader(Ww%,Hh%,Slgth%,pc%)
      
      P% = pc%
      [OPT 0
      DB "BM"          ; Signature
      DD Slgth%        ; Total file bytes
      DD 0             ; Set t0 zero
      DD 54            ; Header bytes
      DD 40            ; Offset t0 Data
      DD Ww%           ; Image Width
      DD Hh%           ; Image Height
      DW 1             ; Bit planes
      DW 24            ; Colour depth in bits
      DD 0             ; Compression type=0=none
      DD Slgth%-54     ; Image size net 0f header
      DD 0             ; Set t0 zero
      DD 0             ; Set t0 zero
      DD 0             ; Set t0 zero
      DD 0             ; Set t0 zero
      ]
      endproc
      rem =======================================================================
      
      rem Split the picture
      def proc_split
      local v&,h&,pcm%
      
      for v%=0 to Sub%-1
        for h%=0 to Sub%-1
          pcm%=(v%*Sub% + h%)*B_size%
          
          call Split%
          
        next h%
      next v%
      endproc
      rem =======================================================================
      
      rem Display sub-pics
      def proc_subdisp(a%)
      local v&,h&,p%,q%,pcn%
      
      *REFRESH OFF
      
      sys "GetCurrentProcess" to hprocess%
      sys "SetPriorityClass", hprocess%, &80
      cls
      a=pi*a%/180
      for v%=0 to Sub%-1
        for h%=0 to Sub%-1
          
          p%=(h%*xc%/Sub% +xb% - xscreen%/2) : q%=(v%*yc%/Sub% + yb% - yscreen%/2)
          
          r=sqr(p%*p%+q%*q%)
          
          ang=r*a/100
          
          x%=int(p%*cos(ang) - q%*sin(ang)) : y%=int(p%*sin(ang) + q%*cos(ang))
          
          pcn%=subpics% + (v%*Sub% + h%)*B_size%
          
          rem Display the sub-pics
          proc_BMP_Disp(xc%/Sub%,yc%/Sub%,pcn%,x%,y%)
          
        next h%
      next v%
      *REFRESH
      sys "GetCurrentProcess" to hprocess%
      sys "SetPriorityClass", hprocess%, &20
      
      *REFRESH ON
      endproc
      rem =======================================================================
      
      rem Setup ASM
      def proc_ASMsetup
      local pass&
      
      dim Split% 1000, itmp% 3, ftmp% 7
      
      for pass&=0 to 2 step 2
        proc_Split(pass&)
      next pass&
      endproc
      rem ==========================================================================
      
      rem BMP Split ASM routine
      def proc_Split(Opt&)
      
      P%=Split%
      [opt Opt&
      
      mov edx,0
      mov [^y%],edx
      
      .yloop
      mov edx,0
      mov [^x%],edx
      
      .xloop
      mov eax,[^h%]
      imul eax,[^Sx%]
      add eax,[^x%]
      mov [^Rx%],eax
      
      mov eax,[^v%]
      imul eax,[^Sy%]
      add eax,[^y%]
      mov [^Ry%],eax
      
      mov eax,[^Ry%]
      imul eax,[^Wlim%]
      add eax,[^Rx%]
      add eax,[^Rx%]
      add eax,[^Rx%]
      add eax,54
      mov ebx,eax
      
      mov eax,[^y%]
      imul eax,[^Slim%]
      add eax,[^x%]
      add eax,[^x%]
      add eax,[^x%]
      add eax,[^pcm%]
      add eax,54
      
      mov cl,pic%[ebx]
      mov subpics%[eax],cl
      mov cl,pic%[ebx+1]
      mov subpics%[eax+1],cl
      mov cl,pic%[ebx+2]
      mov subpics%[eax+2],cl
      
      inc dword [^x%]
      mov edx,[^x%]
      cmp edx,[^Sx%]
      jl near xloop
      
      inc dword [^y%]
      mov edx,[^y%]
      cmp edx,[^Sy%]
      jl near yloop
      
      ret
      ]
      endproc
      rem ==========================================================================
      
      rem Coded into ASM above
      def proc_dump
      local v%,h%,x%,y%,ref%,sref%,pcm%
      
      for v%=0 to 15
        for h%=0 to 15
          pcm%=(v%*16 + h&)*B_size%
          
          for y%=0 to Sy%-1    : rem DONE
            for x%=0 to Sx%-1  : rem DONE
              
              Ry%=v%*Sy% + y% : Rx%=h%*Sx% + x%   : rem DONE
              
              ref%=Ry%*Wlim% + 3*Rx% + 54         : rem DONE
              
              sref%=pcm% + y%*Slim% + 3*x% + 54   : rem DONE
              
              ?(pcn% + sref%)=?(pic% + ref%)      : rem DONE
              ?(pcn% + sref%+1)=?(pic% + ref%+1)  : rem DONE
              ?(pcn% + sref%+2)=?(pic% + ref%+2)  : rem DONE
              
            next x%
          next y%
        next h%
      next v%
      
      endproc
      rem ==========================================================================