rem Scribble .... Rev 2.0
      rem A J Tooth // April 2004
      rem Revised February 2006
      on error if (err=17) then quit
      
      rem Setup
      proc_setup
      
      repeat
        Cnt%+=1 : if Cnt%>1000000 then Cnt%=0 : Flp%=-Flp% : cls
        for k&=1 to 5
          f%(k&)=rnd(3)-2
        next k&
        
        rem Update x% and y%
        x%=fn_limit(x%,f%(1),xscreen%)
        y%=fn_limit(y%,f%(2),yscreen%)
        
        for t&=1 to 3
          if Flp%>0 then Col&(t&)+=f%(2+t&) else Col&(t&)+=f%(t&)
          if Col&(t&)>255 then Col&(t&)=0
          if Col&(t&)<0 then Col&(t&)=255
        next t&
        
        colour 10,Col&(1),Col&(2),Col&(3) : gcol 10
        line 2*x%,2*y%,2*x%+1,2*y%+1
        
        if Cnt% mod 300 = 0 then *REFRESH
        
        a$=inkey$(0)
      until a$<>""
      
      *REFRESH ON
      a$=get$
      
      quit
      end
      rem end of Program +++++++++++++++++++++++++++++++++++++++++++++
      rem ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
      
      rem Setup
      def proc_setup
      *FLOAT64
      rem Call Utility Procedures
      proc_fullscreen  :  rem Set up use of Full Screen
      
      dim Col&(3),f%(5)
      Cnt%=0 : Flp%=1
      x%=rnd(xscreen%) : y%=rnd(yscreen%)
      for i&=1 to 3
        Col&(i&)=rnd(255)
      next i&
      
      *REFRESH OFF
      a$=""
      @vdu%!248=1
      endproc
      rem ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
      
      rem Set up use of Full Screen
      def proc_fullscreen
      
      sys "GetSystemMetrics", 0 to xscreen%
      sys "GetSystemMetrics", 1 to yscreen%
      sys "SetWindowLong",@hwnd%,-16,&16000000
      sys "SetWindowPos",@hwnd%,-1,0,0,xscreen%,yscreen%,0
      vdu 23,22,xscreen%;yscreen%;8,16,16,1 : rem Set fullscreen mode
      mouse off : off : rem Turns off the Mouse Pointer and the Cursor
      endproc
      rem ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
      
      def fn_limit(Zz%,Stp%,Xt%)
      
      Zz%+=Stp%
      if Zz%<0 then Zz%=Xt%
      if Zz%>Xt% then Zz%=0
      =Zz%
      rem ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++